*CMZ :  2.04/00 23/11/94  14.22.33  by  Charles F. Maguire
*-- Author :    John P. Sullivan   07/01/94
      SUBROUTINE VER_FRAM (COLOR_VER)
C

      implicit none

      include 'g77trigdef.inc'

C
C     Description:-
C     =============
C          This subroutine defines the geometry for the "frame"
C          of the central barrel of the MVD. Originally, this
C          set up the rohacell cages and the "mounting plates"
C          at each end of the MVD. Now it just sets up the
C          "mounting plates". The rohacell C-cages are defined
C          elsewhere.
C
C     Author:-
C     ========
C          JPSullivan
C
C     Creation Date: 6-Jan-1994 (based on code previously in ver)
C     ===========================
C
C     Revisions:-
C     ===========
C           Date    Name  Description
C           ----    ----  ----------------------------------------
C      13-Sep-00    JPS   remove code to define rohacell C-cages,
C                         remove ver_delphi from calling sequence.
C
C     Arguments:-
C     ===========
C
      INTEGER COLOR_VER         ! Color code for MVD
C
C     Implicit inputs, outputs, side effects:-
C     ========================================
C
C          Called by: VER
C          Calls    : GSVOLU, GSATT, GSPOS, GSROTM
C
C          Implicit input:
C          Most of the geometry parameters are taken
C          from the zebra bank with offset LFV_PARA (from keep FPVLINK). This
C          bank should be created and filled before calling this routine.
C          Currently, this is done in subroutine VER_PARS.
C
C          Implicit output:
C          The geant geometry banks are modified since this routine creates
C          and positions the geant volumes for the MVD central barrel s frame.
C          Some new rotation matrices are also defined.
C
C     Global Specifications:-
C     =======================
C
C GCUNIT contains defintion of logical unit LOUT
C +CDE,GCUNIT.
*KEEP,FSTORE.
      include 'fstore.inc'
*KEEP,SUBLINK.
      include 'sublink.inc'
*KEEP,FPVLINK.
      include 'fpvlink.inc'
*KEEP,GUGEOM.
      include 'gugeom.inc'
*KEND.
C
C     External Specifications:-
C     =========================
C     None
C
C     Local Specifications:-
C     ======================
C
C-->  Parameters controlling the size of the frame taken from
C     the Zebra geometry bank
C
      REAL VISLR            ! Radius for VISL
      REAL VOSLR            ! Radius for VOSL
C
      INTEGER MED_VER_ROH   ! Rohacell support structure
C
C-->  Azimuthal angle to the middle of inner or outer panels:
C
      REAL R_VER_MOPL
      INTEGER MED_VER_MOPL
      REAL DZ_VER_MOPL
      REAL  Z_VER_MOPL
C
      REAL PAR_VTMP(3)      !temporary variable
      REAL POS_VTMP(3)      !temporary variable
C
      INTEGER    NMED    ! Medium number
      INTEGER    IVOLU
      INTEGER    I       ! Loop index
      REAL       RADIUS  ! Perpendicular distance to beam axis
C
C===========================================================================
C
      VISLR       = QF(LFV_PARA + OFVA_VISLR)
      VOSLR       = QF(LFV_PARA + OFVA_VOSLR)
      MED_VER_ROH = QF(LFV_PARA + OFVA_MED_ROH)
      R_VER_MOPL  = QF(LFV_PARA + OFVA_R_MOPL)
      MED_VER_MOPL= NINT(QF(LFV_PARA + OFVA_MED_MOPL))
      DZ_VER_MOPL = QF(LFV_PARA + OFVA_DZ_MOPL)
       Z_VER_MOPL = QF(LFV_PARA + OFVA_Z_MOPL)
C
CCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCC
C
      NMED        = MED_VER_MOPL
      PAR_VTMP(1) = VISLR
      PAR_VTMP(2) = R_VER_MOPL
      PAR_VTMP(3) = DZ_VER_MOPL
      CALL GSVOLU ( 'VMPL','TUBE',NMED,PAR_VTMP,3,IVOLU )
      CALL GSATT  ( 'VMPL','SEEN',1 )
      CALL GSATT  ( 'VMPL','COLO',COLOR_VER )
C
      POS_VTMP(1) = 0.
      POS_VTMP(2) = 0.
      POS_VTMP(3) = Z_VER_MOPL
      CALL GSPOS ( 'VMPL',1,'VERT',POS_VTMP(1),POS_VTMP(2),
     x             POS_VTMP(3),IROTNULL,'ONLY' )
      POS_VTMP(3) = -POS_VTMP(3)
      CALL GSPOS ( 'VMPL',2,'VERT',POS_VTMP(1),POS_VTMP(2),
     x             POS_VTMP(3),IROTNULL,'ONLY' )
C
      RETURN
      END